红枫吟 - Emacs

让Eglot支持tailwindcss以及多个LSP服务

Fri, 02 Jan 2026 00:39:44 +0000

前言

虽然我不是专业的前端开发人员，但偶尔还是会写一下 HTML/CSS/Javascript 或者Vue。在一个 HTML 文件中，我需要使用多个 LSP服务，比如使用 vscode-html-language-server 补全css样式，使用tailwindcss-language-server 补全tailwindcss的class名称，使用 vscode-eslint-language-server 检查语法

但我目前使用的Emacs lSP客户端 Eglot 一直不支持多个LSP服务，目前的解决方式有两种，一是把 Eglot 更换为 lsp-mode 或者 lsp-bridge，二是使用第三方命令行代理服务，比如:

lspx 是因为我的电脑上没有相关环境，无法编译，rass 是由 Eglot 的作者开发，不过看情况他是准备把 rass 作为一个通用的LSP代理，所以配置文件会单独放置到 HOME 目录，这一点我不是很喜欢

算了，找来找去还不如自己写一个(轮子+1)，eglot-lspx，一个多LSP代理服务，用于解决 Eglot 无法使用 tailwindcss 以及不支持多个LSP服务的问题

如何使用？

编译

1git clone https://github.com/honmaple/eglot-lspx
2cd eglot-lspx
3go build .

然后把编译好的 eglot-lspx 文件放到可执行路径下，比如我放到了 ~/.emacs.d/bin 目录，并添加路径到Emacs配置

1(add-to-list 'exec-path (expand-file-name "bin" user-emacs-directory) t)

配置Eglot

 1(defvar eglot-lspx-command (executable-find "eglot-lspx"))
 2
 3(when eglot-lspx-command
 4  (add-to-list 'eglot-server-programs `((web-mode :language-id "html")
 5                                        . (,eglot-lspx-command
 6                                           "--" "vscode-html-language-server" "--stdio"
 7                                           "--" "tailwindcss-language-server" "--stdio")))
 8  (add-to-list 'eglot-server-programs `((vue-mode :language-id "html")
 9                                        . (,eglot-lspx-command
10                                           "--" "vue-language-server" "--stdio"
11                                           "--" "vscode-html-language-server" "--stdio"
12                                           "--" "tailwindcss-language-server" "--stdio"
13                                           :initializationOptions
14                                           (lambda (server) (list :vue-language-server (eglot-volar-options server)))))))

合并补全信息
```
1--provider completion=0,tailwindcss-language-server
```
可以使用LSP服务名或者索引名，使用逗号分隔，索引名即第n个LSP服务，从0开始，未设置将合并全部

示例

为maple-translate增加更友好的sdcv离线翻译

Mon, 22 Apr 2024 21:51:27 +0000

之前我写的Emacs翻译插件 maple-translate 有一个 sdcv 离线翻译的功能，它使用了 Elisp 解析 StarDict 的字典文件，所以不需要安装其它任何依赖。但是也是因为此原因，首次使用离线翻译需要等待字典文件加载到内存，这不是很友好，此次我将添加 sdcv 二进制文件的支持，使离线翻译能够更加快捷方便

首先是安装 sdcv 二进制文件

 1└──╼ brew install sdcv
 2└──╼ sdcv --help
 3用法：
 4  sdcv [选项…]  words
 5
 6帮助选项：
 7  -h, --help                     显示帮助选项
 8
 9应用程序选项：
10  -v, --version                  display version information and exit
11  -l, --list-dicts               display list of available dictionaries and exit
12  -u, --use-dict=bookname        for search use only dictionary with this bookname
13  -n, --non-interactive          for use in scripts
14  -j, --json-output              print the result formatted as JSON
15  --json                         print the result formatted as JSON
16  -e, --exact-search             do not fuzzy-search for similar words, only return exact matches
17  -0, --utf8-output              output must be in utf8
18  -1, --utf8-input               input of sdcv in utf8
19  -2, --data-dir=path/to/dir     use this directory as path to stardict data directory
20  -x, --only-data-dir            only use the dictionaries in data-dir, do not search in user and system directories
21  -c, --color                    colorize the output

然后定义二进制文件的路径，如果 sdcv 未安装，则返回为 nil

1(defvar maple-translate-sdcv-program (executable-find "sdcv"))

接着修改之前写好的 maple-translate-sdcv 函数，通过判断 maple-translate-sdcv-program 是否为空采取不同的翻译操作

 1(defun maple-translate-sdcv(word &optional callback)
 2  "Search WORD with sdcv, use async request if CALLBACK non-nil."
 3  (if maple-translate-sdcv-program
 4      (maple-translate-execute maple-translate-sdcv-program
 5        :args (append '("-n" "-x" "-j" "-0" "-1" "-2")
 6                      (cl-loop for dict in maple-translate-sdcv-dicts
 7                               collect (expand-file-name (cdr dict) maple-translate-sdcv-dir))
 8                      (list word))
 9        :format (maple-translate-sdcv-format)
10        :callback callback)
11    ;; ...
12    ;; 使用ELisp解析并翻译
13    ))

需要说明的是，由于该函数接收一个 callback 的变量，用于处理异步翻译，如果是同步翻译，可以直接使用 call-process 获取结果

1(with-temp-buffer
2  (apply 'call-process "sdcv" nil t nil '("-n" "-x" "-j" "-0" "-1" "-2" "/Users/xxx/.emacs.d/stardict/stardict-lazyworm-ec-2.4.2" "word"))
3  (buffer-string))

但如果是异步翻译，则需要使用 start-process ，再通过监听进程状态在进程结束后再获取翻译结果

1(let ((name (format "maple-translate-process %s" ,program)))
2  (set-process-sentinel
3   (apply 'start-process name (format "*%s*" name) ,program ,args)
4   (lambda(process _)
5     (unless (process-live-p process)
6       (with-current-buffer (process-buffer process)
7         (prog1 (funcall ,callback ,format)
8           (kill-buffer (current-buffer))))))))

这里的 buffer 名称也可以通过 (generate-new-buffer " *temp*" t) 生成一个临时 buffer

最后就是翻译结果的展示，由于输出的是多行 json，比如:

1[]
2[{"dict": "懒虫简明英汉词典","word":"word","definition":"\n[wә:d]\nn.\n字, 词, 话, 消息, 诺言, 命令\nvt.\n为...措辞"}]

所以我在解析翻译结果时取了个巧，没有使用 (buffer-string) 而是直接在 buffer 里操作，每次都跳到开始位置，再依次向下移动 n 行，这个 n 即是字典的数量，最后使用 (thing-at-point 'line t) 获取当前行的数据

 1(defun maple-translate-sdcv-format()
 2  "Format result with sdcv output."
 3  (let ((results (cl-loop for index from 0
 4                          for dicts in maple-translate-sdcv-dicts
 5                          collect
 6                          (progn
 7                            (goto-char (point-min))
 8                            (forward-line index)
 9                            (string-join (cl-loop for child across-ref (json-read-from-string (decode-coding-string (thing-at-point 'line t) 'utf-8))
10                                                  collect (format "%s: %s"
11                                                                  (alist-get 'dict child)
12                                                                  (alist-get 'definition child)))
13                                         "\n\n")))))
14    (unless (null results)
15      (string-join (cl-remove nil results) "\n\n"))))

最终效果

maple-translate的具体修改可见: dfd0eae

重复造轮子之Emacs翻译插件maple-translate

Fri, 03 Nov 2023 22:19:03 +0000

我之前一直都在使用 youdao-dictionary 这个插件，虽然没有配置过秘钥，这时会有使用次数的限制(反正是每天1000次还是多少来着，有些忘了)，但是我平时使用次数不多，所以也不会达到使用限制，不管是单词翻译还是长句翻译都很不错。但最近几个月 youdao-dictionary 如果不配置私钥，处于一个完全不可用的状态。

我曾寻找过它的替代品，并且使用过一段时间的 fanyi.el，不可否认，这同样是一个非常不错的插件，不管是UI还是功能，但是，可能是因为 fanyi.el 使用异步请求的原因，偶尔会出现一些意想不到的报错，更重要的是它不支持长句翻译和离线翻译。

考虑再三，还是决定自己造一个轮子，主要功能就按照我之前使用 youdao-dictionary 的习惯:

翻译光标下的单词，以及选中的单词或句子

翻译的内容输出到 echoarea 或者新的 buffer，方便复制

增加一个离线翻译的功能，并且可以不依赖外部工具

基于上述，所以有了这个新的轮子 maple-translate

如何使用?

可以使用 quelpa 安装

1(use-package maple-translate
2  :quelpa (:fetcher github :repo "honmaple/emacs-maple-translate")
3  :commands (maple-translate maple-translate+))

或者手动下载仓库

1git clone https://github.com/honmaple/emacs-maple-translate ~/.emacs.d/site-lisp/maple-translate

然后进行配置

1(use-package maple-translate
2  :ensure nil
3  :commands (maple-translate maple-translate+))

长句翻译

~~目前长句翻译仅支持 youdao~~, 目前支持 youdao 和 google 两种翻译引擎，可以修改设置

1(setq maple-translate-engine 'youdao)
2;; 或者
3(setq maple-translate-engine 'google)

谷歌翻译

国内无法直接使用，但是可以单独为谷歌翻译设置代理

1(setq maple-translate-google-url "https://translate.googleapis.com/translate_a/single")
2(setq maple-translate-google-proxies
3      '(("http" . "127.0.0.1:1086")
4        ("https" . "127.0.0.1:1086")))

离线翻译

我个人平时在使用 Emacs 时不太习惯依赖外部的工具，比如我之前就写过一个markdown，org-mode实时预览插件 maple-preview，它区别于其它插件，并不会依赖外部的工具，比如 Pandoc，甚至不会生出任何文件到我的本地环境

同样的，我也不希望使用离线翻译时还要依赖外部诸如 sdcv，goldendict 等工具，我想要直接使用 Elisp 来对词典进行解析。所幸前人栽树，后人乘凉，已经有了一个纯 Elisp 实现的解析器 https://www.emacswiki.org/emacs/stardict.el

我所需要做的，就是下载需要的词典到本地(这个步骤是必须的，即使我不喜欢)，然后设置

1;; 离线词典所在的目录
2(setq maple-translate-sdcv-dir "~/.stardict/dicts")
3;; 所使用的词典 -> (词典名词 . 词典具体目录)
4(setq maple-translate-sdcv-dicts
5      '(("lazyworm-ec" . "stardict-lazyworm-ec-2.4.2")
6        ("lazyworm-ce" . "stardict-lazyworm-ce-2.4.2")))

最后修改翻译引擎

1(setq maple-translate-engine 'sdcv)

注意：第一次使用离线翻译需要等待词典初始化，这会需要耗费一段时间，后面就快了

多引擎翻译

maple-translate 同样支持多引擎，需要修改设置为一个列表

1(setq maple-translate-engine '(youdao dictcn sdcv))

翻译原理

目前支持的几个引擎: youdao(有道)、dictcn(海词)、iciba(金山词霸)、bing(必应)、google(谷歌)、sdcv(离线)。除 sdcv 外，其它几个都依赖于网络，maple-translate 可以看作是一个爬虫，通过爬取翻译页面，然后使用Emacs内置的 dom 对HTML进行解析，最后获取到想要的内容(谷歌使用API获取)。基于此，我还写了一个超简单的 类xpath 解析器

 1(defun maple-translate-dom-by-key(dom key)
 2  (let (func num)
 3    (when (string-match "\\[\\([0-9]+\\)\\]" key)
 4      (setq num (match-string 1 key))
 5      (setq key (substring key 0 (- (length key) (length num) 2))))
 6    (cond ((string-prefix-p "." key)
 7           (setq key (substring key 1) func 'dom-by-class))
 8          ((string-prefix-p "#" key)
 9           (setq key (substring key 1) func 'dom-by-id))
10          ((string-prefix-p "*" key)
11           (setq func (lambda(p _) (dom-children p))))
12          (t (setq key (intern key) func 'dom-by-tag)))
13    (if (null num)
14        (funcall func dom key)
15      (nth (string-to-number num) (funcall func dom key)))))
16
17(defun maple-translate-dom-find(dom xpath)
18  (cl-loop for key in (string-split (string-trim xpath) "/")
19           if (consp dom)
20           do (setq dom (maple-translate-dom-by-key dom key))
21           else return dom)
22  dom)

这样，我就能通过一些简单的语法来定位想要的内容，比如在有道里面使用

1(maple-translate-dom-find dom ".simple dict-module/.trans-container/.word-exp")

获取到 class 名称为 simple dict-module 下的 class 名称为 trans-container 下的 class 名称为 word-exp 的所有元素, 也就是基本释义

Emacs笔记之修复yaml-mode的格式化问题

Tue, 21 Feb 2023 17:18:40 +0000

更新时间	备注
2023-02-26	增加更多判断逻辑, 比如上一行是列表，当前行也是列表，则按正常缩进计算

一直以来 yaml-mode 都有一个问题，在使用 (indent-region (point-min) (point-max)) 时已经格式好的内容总是会得到错误的缩进，比如一个简单的配置

1test1: "val"
2test2:
3  - "val1"
4  - "val2"
5test3:
6  test4: "val4"

在调用 indent-regin 后就会变成

1test1: "val"
2test2:
3  - "val1"
4  - "val2"
5  test3:
6    test4: "val4"

而我又总是手痒，写好的配置文件总是会忍不住 indent-region 一番，结果本来正确的格式立马变得各种乱七八糟，当初为了解决这个问题，还专门为 yaml-mode 激活了 lsp-mode, 并且使用 lsp-format-buffer 来进行处理。

本来一切都还正常，但最近发现了另外一个问题，如果在 org-mode 中插入 yaml 的代码片段，调用 indent-region 还是还有之前的问题, org-mode 中又无法直接调用 lsp-format-buffer, 所以专门研究了一下 yaml-mode

发现 yaml-mode 只是定义了 indent-line-function 变量，没有定义 indent-region-function, 导致调用 indent-region 时其实是逐行调用 yaml-indent-line, 这里面有一个计算当前缩进的 yaml-compute-indentation 函数，计算方式有些简单粗暴，如果上一行是一个 hash key, 当前行的缩进就是上一行的缩进加 yaml-indent-offset 的值, 这里并没有判断当前行是新建行还是已经有相关内容，如果是新建行那么缩进就是对的，如果是已有的内容就是错的，所以我修改了这一部分逻辑，如果是 已有内容并且当前行的缩进小于上一行 则不进行处理, 比如:

1  - "val2"
2test3:

虽然增加的判断逻辑很简单，但至少在使用 indent-region 时已经格式好的内容就不会出现混乱的情况了, 也不用专门为 yaml 文件激活一个 lsp 进程。

目前处理的方式还是采用 advice + letf 形式，否则需要修改很多内容，有兴趣的同道可以参考一下

 1(defun maple/yaml-compute-indentation()
 2  (let ((ci (current-indentation))
 3        (cm (looking-at yaml-hash-key-re))
 4        (cl (looking-at "^\s*-\s+.*$")))
 5    (save-excursion
 6      (beginning-of-line)
 7      (if (looking-at yaml-document-delimiter-re) 0
 8        (forward-line -1)
 9        (while (and (looking-at yaml-blank-line-re)
10                    (> (point) (point-min)))
11          (forward-line -1))
12        (let ((li (current-indentation))
13              (ll (looking-at "^\s*-\s+.*$")))
14          ;; 如果上一行的缩进大于当前行, 上一行是列表，当前行也是是列表 - 正常缩进
15          ;; 如果上一行的缩进大于当前行, 上一行和当前行有一个不是列表 - 原有缩进
16          ;; 如果上一行的缩进等于当前行, 上一行是字典，当前行是列表 - 正常缩进
17          ;; 如果上一行的缩进等于当前行, 上一行是字典，当前行是不是列表 - 原有缩进
18          ;; 如果上一行的缩进小于当前行, 上一行是字典 - 正常缩进
19          ;; 如果上一行的缩进小于当前行, 上一行是列表，当前行也是列表 - 正常缩进
20          ;; 如果上一行的缩进小于当前行, 上一行是列表，当前行是字典 - 错误/正常缩进
21          (if (or (and (> li ci) (or (not cl) (not ll))) (and (= li ci) cm (not ll))) ci
22            (+ li
23               (if (looking-at yaml-nested-map-re) yaml-indent-offset 0)
24               (if (looking-at yaml-nested-sequence-re) yaml-indent-offset 0)
25               (if (looking-at yaml-block-literal-re) yaml-indent-offset 0))))))))
26
27(defun maple/yaml-indent-region(func &rest args)
28  (if (derived-mode-p 'yaml-mode)
29      (letf (((symbol-function 'yaml-compute-indentation) 'maple/yaml-compute-indentation))
30        (apply func args))
31    (apply func args)))
32
33(advice-add 'indent-region :around 'maple/yaml-indent-region)

Emacs笔记之minibuffer默认输入

Thu, 25 Nov 2021 22:14:00 +0000

在使用 evil-ex，也就是冒号+命令时，有一个非常有趣的功能，输入冒号后，minibuffer 会显示上一次执行的命令，比如 :wq, 确认可以直接执行这个命令，但是输入任意字符，就会把原先的 wq 直接覆盖，接收新的命令输入

我觉得这是一个非常有趣且有用的功能，像 read-string 函数，如果我想要一个默认的输入，可以直接使用

1(let ((input (read-string "prompt: " "默认内容")))
2  (message input))

但我想覆盖这个默认, 则需要先把 默认内容 删除，再输入我想要的字符, 如果不想先删除默认再输入，还可以使用

1(let ((input (read-string "prompt: " nil nil "默认内容")))
2  (message input))

但是这样的话我无法看到默认的内容，当然，也许可以把默认内容追加到 prompt 里，我认为这样不太好看，不是吗

1(let* ((default "默认内容")
2       (input (read-string (format "prompt (default %s): " default) nil nil default)))
3  (message input))

evil-ex 提示我一个新的解决方式, 通过查看 evil-ex 源码，可以发现它是使用 minibuffer-with-setup-hook 和 after-change-functions 在minibuffer里插入新内容时先清理默认内容, 再插入新内容, 我简化了相关代码

 1(let ((input (minibuffer-with-setup-hook 'maple-input-setup
 2               (read-string "prompt: " (propertize "默认内容" 'face 'shadow)))))
 3  (message input))
 4
 5(defun maple-input-setup()
 6  (add-hook 'after-change-functions 'maple-input-update nil t))
 7
 8(defun maple-input-update(&optional beg end len string)
 9  (let ((string (buffer-substring-no-properties beg end)))
10    (delete-minibuffer-contents)
11    (insert string)
12    (remove-hook 'after-change-functions 'maple-input-update t)))

OK, 就这样

Emacs自动插入更新文件头——maple-header

Wed, 06 Oct 2021 14:57:51 +0000

一个简单的插件，可以在文件创建时自动插入文件头，或者文件更新时自动更新文件头信息，虽然已经用了好几年，这次把相关代码提取并精简一下做成了插件 maple-header

安装

使用quelpa

1(use-package maple-header
2  :quelpa (:fetcher github :repo "honmaple/emacs-maple-header")
3  :hook (after-init . maple-header-mode))

克隆到本地

1git clone https://github.com/honmaple/emacs-maple-header --depth=1 ~/.emacs/site-lisp/maple-header

配置

1(use-package maple-header
2  :ensure nil
3  :hook (after-init . maple-header-mode))

基础配置

1;; 更新文件头时搜索的文件函数, 9代表只会搜索前9行
2(setq maple-header:lines 9)
3;; 创建新文件时是否自动插入文件头信息
4(setq maple-header:auto-insert t)
5;; 更新文件时是否自动更新文件头信息
6(setq maple-header:auto-update t)

自定义模版

比如我要自定义Python文件的文件头

1(add-to-list 'maple-header:auto-insert-alist
2             '((python-mode . "Python program") nil
3               "#!/usr/bin/env python\n"
4               "# -*- coding: utf-8 -*-\n"))

自定义更新

目前内置了 filename, email, modify 三个字段, 可以通过调用 maple-header:update-xxx 手动更新指定的字段, 如果需要增加新的或者覆盖原字段,可以使用

1(add-to-list 'maple-header:auto-update-alist '(author . custom-update-author))
2
3(defun custom-update-author(&optional current-line)
4  (interactive)
5  (maple-header:update-action
6   ".*\\(Author:\\)\\(.*\\)"
7   user-full-name current-line))

使用 maple-header:update 会更新所有字段(包括：filename，email，modify，author), 如果只需要更新部分，需要修改为

1(setq maple-header:auto-update-alist
2      '((filename . maple-header:update-filename)
3        (modify . maple-header:update-modify)))

Emacs快速创建侧边栏——maple-explorer

Sat, 09 Nov 2019 23:02:12 +0000

闲着没事又造了一个轮子，:smile:

maple-explorer 是一个用于快速创建类似neotree文件浏览，或者类似maple-imenu的变量函数浏览的侧边栏的插件，让每个人都能写一个属于自己的侧边栏

emacs-maple-explorer

快速创建一个侧边栏: 只需要定义一个maple-explorer-NAME-list的函数，并且返回一个列表

1(list
2 :name name
3 :value value
4 :face face
5 :click click
6 :status 'close ;; or 'open
7 :children '((child1 child2 ...))

其中child1，child2格式与父列表格式一致，child1中也可以嵌套下一组children，比如我定义一个名为aaa的list的函数:

 1(defun maple-explorer-aaa-list(&optional isroot)
 2  "Get recentf file list ISROOT mean first call."
 3  (list
 4   :name "aaa"
 5   :value "aaa"
 6   :face 'font-lock-constant-face
 7   :click 'maple-explorer-fold
 8   :status 'open
 9   :children
10   (list
11    (list :name "aaa_child1"
12          :face 'font-lock-keyword-face
13          :click (lambda() (interactive) (message "bbb")))
14    (list :name "aaa_child2"
15          :face 'font-lock-comment-face
16          :click (lambda() (interactive) (message "aaaa"))))))

定义好后只要使用 (maple-explorer-define aaa) 就能快速创建一个maple-explorer-aaa的函数，使用它就能打开一个侧边栏，效果是这样的

自定义内容显示: maple-explorer提供了一个maple-explorer-NAME-name-function的变量，可用于自定义内容的显示，比如对于一个文件列表，我可以增加自定义图标

 1(defun maple-explorer-icon (str icon)
 2  "The ICON of maple-explorer STR."
 3  (format "%s %s" (propertize "\t" 'display icon) str))
 4
 5(defun maple-explorer-icon-file-name(info)
 6  "Custom maple-explorer-file INFO icon name."
 7  (let ((name  (plist-get info :name))
 8        (value (plist-get info :value)))
 9    (plist-put info :indent 5)
10    (cond ((or (string= name ".") (string= name ".."))
11           (maple-explorer-icon name (all-the-icons-faicon "folder")))
12          ((file-directory-p value)
13           (maple-explorer-icon
14            name
15            (if (maple-explorer--is-open info)
16                (all-the-icons-faicon "folder-open")
17              (all-the-icons-faicon "folder"))))
18          (t (maple-explorer-icon name (all-the-icons-icon-for-file value))))))
19
20(setq maple-explorer-file-name-function 'maple-explorer-icon-file-name)

自定义之前是这样的

自定义之后是这样的

更多信息 maple-explorer目前已实现了

1maple-explorer-file      ;; 文件浏览
2maple-explorer-imenu     ;; 函数变量名浏览
3maple-explorer-buffer    ;; 已打开buffer浏览
4maple-explorer-recentf   ;; 最近文件浏览
5maple-explorer-project   ;; 已打开的项目浏览

欢迎各位emacs同道测试

Emacs下一键执行代码(可输入)——maple-run

Tue, 17 Sep 2019 04:31:25 +0000

之前一直使用quickrun来执行一些代码片段，但quickrun有一个问题就是无法输入，比如python代码

1a = input("aaaaa: ")
2print(a)

需要建立一个qrinput的文件，太过麻烦，所以我平时测试一些需要输入的python代码时会使用

1(defun maple/run-python ()
2  (interactive)
3  (or (python-shell-get-process) (call-interactively 'run-python))
4  (if (use-region-p)
5      (python-shell-send-region (region-beginning) (region-end) t)
6    (python-shell-send-buffer t)))

但退出python shell又需要手动输入exit()，我是一个怕麻烦的人，所以写了一个可供输入的 emacs-maple-run 来一键执行当前buffer的代码(后面发现quickrun其实也可以通过quickrun-shell来提供实时输入，不过使用的是eshell)

目前只加了python,go,lua,html的执行命令，自定义只需要使用

1(add-to-list 'maple-run:alist '(python-mode :command "python %F"))
2(add-to-list 'maple-run:alist '(c-mode :command "gcc %F -o %b && ./%b"))
3(add-to-list 'maple-run:alist '((html-mode web-mode) :command browse-url-of-file))

另外，maple-run也提供了一个非常方便的函数 (maple-run:script process-name program prgram-args) 来供用户自定义命令，比如:

打开一个bash shell
```
1(maple-run:script nil "bash")
```
打开一个ipython shell
```
1(maple-run:script nil "ipython")
```

执行golang代码

1(maple-run:script nil "go" "run" (buffer-file-name))

默认的执行方式

1(maple-run:script nil "bash" "-c" "python file.py")

Emacs环境隔离之——maple-env

Mon, 15 Jul 2019 13:34:27 +0000

在使用Emacs时，会有很多依赖，比如:

Python依赖于flake8，isort，python-language-server等
Golang依赖于golang.org/x/tools/cmd/gopls，github.com/haya14busa/gopkgs/cmd/gopkgs等

想要安装这些依赖，必须手动进行安装，use-package用户可使用ensure-system-package，但非常不幸的是，这些依赖很大程度上会污染我的电脑环境，毕竟像python-language-server，flake8这类的package，我除了在Emacs里会用到，平时根本用不到（除非同时使用Emacs和其它编辑器或IDE）

所以，我写了一个maple-env用来实现Emacs依赖环境隔离，使用方式:

安装

1git clone https://github.com/honmaple/emacs-maple-env ~/.emacs/site-lisp/maple-env

配置

 1(use-package maple-env
 2  :ensure nil
 3  :hook (after-init . maple-env-mode)
 4  :config
 5  (setq maple-env:python-packages
 6        '("yapf" "flake8" "isort" "python-language-server")
 7        maple-env:golang-packages
 8        '("github.com/rogpeppe/godef"
 9          "github.com/golang/lint/golint"
10          "github.com/haya14busa/gopkgs/cmd/gopkgs"
11          "golang.org/x/tools/cmd/gopls")
12        maple-env:npm-packages
13        '("js-beautify"))
14  ;; 手动调用(maple-env:init)以安装依赖环境
15  )

更多自定义详见customize-group maple-env

elisp生成渐变XPM图片

Fri, 12 Jul 2019 18:21:04 +0000

无意中看到 telephone-line 有一种渐变颜色的效果，看起来很棒，但telephone-line的源码有些难懂，所以自己动手实现类似的效果

渐变颜色

渐变颜色的实现可使用color-gradient

1(color-gradient
2 '(0 0 0)
3 (color-name-to-rgb "red") 10)

实现原理是对红(R)、绿(G)、蓝(B)三个颜色通道分别取 n + 2 个过渡值，n 为中间颜色过渡状态，所以对于red、#000、#a0a0a0等颜色需要转化为RGB色彩模式

生成XPM图片

XPM图片格式参考 https://en.wikipedia.org/wiki/X_PixMap(XPM3)

大概是这样的

 1/* XPM */
 2static char * XFACE[] = {
 3/* <Values> */
 4/* <width/columns> <height/rows> <colors> <chars per pixel>*/
 5"48 4 2 1",
 6/* <Colors> */
 7"a c #ffffff",
 8"b c #000000",
 9/* <Pixels> */
10"abaabaababaaabaabababaabaabaababaabaaababaabaaab",
11"abaabaababaaabaabababaabaabaababaabaaababaabaaab",
12"abaabaababaaabaabababaabaabaababaabaaababaabaaab",
13"abaabaababaaabaabababaabaabaababaabaaababaabaaab"
14};

渐变颜色XPM图片原理就是使用不同的字符代表不同状态的渐变颜色，当所使用的字符数越多，渐变效果越好，但同时XPM图片的宽度也就越大

生成不同字符

1;; 0～9
2(mapcar 'number-to-string (number-sequence 0 9))
3;; a~z
4(mapcar 'char-to-string (number-sequence ?a ?z))

不同字符对应不同颜色

1(let ((number -1))
2  (mapconcat
3   (lambda(x)
4     (setq number (+ number 1))
5     (format "\"%s c %s\"," (nth number maple-xpm-chars) (apply 'color-rgb-to-hex x)))
6   (color-gradient
7    (color-name-to-rgb color1)
8    (color-name-to-rgb color2) width) ""))

效果显示

完整代码及更多XPM图片